Podemos pensar en un alias como un nuevo comando u orden para mIRC que creamos nosotros mismos. De esta forma automatizamos un proceso a fin de poderlo ejecutar más fácilmente. 

Encontraremos todos los alias de que disponemos en un momento determinado, en el menú TOOLS opción "aliases", es  ahí donde debemos escribir los nuevos alias que creemos, o modificar los existentes, una vez hecho esto pulsaremos el botón OK, y el alias ya quedará cargado en nuestro programa. 

No obstante, antes de empezar a crear y modificar alias es preciso tener un buen conocimiento de los comandos del mIRC, puesto que son ellos los que forman el núcleo fundamental de las ordenes que se emplean en un alias. 

La definición de un alias se compone de dos partes: el nombre o patrón del alias, y las instrucciones que se ejecutarán cada vez que llamemos a este alias. Vamos a verlo con un ejemplo sencillo:  /entra /join #ayuda_irc 

Este alias se llama "entra", y cada vez que en la línea de escritura pongamos: /entra, el programa ejecutará el comando: /join #ayuda_irc.  

Obsérvese que el nombre del alias debe de ir precedido del símbolo de comando "/". A continuación del nombre pondremos un espacio en blanco, y las ordenes que queremos que el alias ejecute al ser invocado. Estas ordenes serán normalmente otros comandos u otros alias. No es recomendable el uso de la recursividad, es decir, emplear el nombre del alias que estamos definiendo dentro de su propia definición. 

Si en la definición del alias queremos especificar varios comandos u ordenes, no nos vale la sintaxis anterior, a estos efectos disponemos de las llaves {} para encerrar todas las líneas del alias: 

/entra {  

nick Muphet  
join #Madrid  
join #programación  
mode Muphet +i 

} 

Este alias cambiará nuestro nick, nos introducirá en los canales #Madrid y #programación, y pondrá nuestro modo de usuario en +i (invisible). 

También sería posible especificar todos los comandos de alias en una sola línea utilizando el símbolo | (suele ser la combinación Alt Gr + 1): 
  /entra /nick Muphet | /join #Madrid | /join #programación | /mode Muphet +i 

Evidentemente los alias no serian lo que son si no permitieran una mayor flexibilidad en sus definiciones. Imaginemos que no queremos especificar un nick para el alias /entra, ni tampoco los canales en que este nos debe de introducir, sino que deseamos que estos sean los que decidamos en cada momento que ejecutamos el alias. Esto es posible utilizando identificadores posicionales del tipo $nº de la siguiente forma: 

/entra {  

nick $1  
join $2  
join $3  
mode $1 +i 

} 

De esta forma el alias esperará que nosotros especifiquemos el nick y los canales a continuación de la llamada, y sustituirá $1, $2, y $3 por la primera, segunda, y tercera palabra que escribamos detrás de la orden /entra. Para lograr el mismo resultado que antes deberemos escribir: 
  /entra Muphet #Madrid #programación   
Sin embargo, ahora podremos decidir un nick y canales diferentes con solo ponerlos a continuación del nombre del alias, por ejemplo: 
  /entra SomaTic #ayuda_irc #opers_help   
Aún más, podemos hacer que el propio programa nos pregunte en una ventana de diálogo cual es el valor que queremos introducir en el alias, empleando el parámetro $?. Por ejemplo: 
  /j /join $?="Elige canal" 

Cuando llamemos a alias /j, nos aparecerá una ventana que nos dirá: "Elige el canal", y el programa nos introducirá en el canal que especifiquemos. 

Un identificador muy útil que se usa en combinación con $? es $!. Este nos permite recuperar el valor que hemos introducido en la ventana de diálogo, sin necesidad de tenerlo que escribir de nuevo. Por ejemplo: 

/MiNick {  

nick $?="Introduce tu nuevo nick"  
say ¿Que os parece mi nuevo nick: $! ? 

} 

El comando /say es una orden que solo se ejecuta desde dentro de un script, y equivale al comando /msg #. Es decir envía un mensaje al canal actual. 

Si a la hora de invocar un alias que contiene parámetros posicionales o del tipo $? omitimos la palabra por la cual estos deben de ser sustituidos (no ponemos un nick o unos nombres de canal en los ejemplos anteriores), el programa intentará ejecutar de todos modos el alias, y en la mayoría de los casos se producirá un error. Una alternativa interesante es hacer uso de la variación $$nº ó $$?. El doble signo $ hace saber al programa que si en la llamada a un alias no se da un valor a ese parámetro, debe de ignorar la orden. Por ejemplo: 
  /saludo /say Hola $$1 , $2 , $3 .Este es el canal de la diversión !!   
Podemos ejecutar el alias /saludo especificando hasta tres nombres o palabras para ser incluidas en la línea del /say, pero funcionará igualmente si ponemos solo dos o una; sin embargo, si no damos al menos un valor tras la llamada /saludo el programa lo ignorará y no ejecutará acción alguna. 

Obsérvese que hemos tenido la precaución de definir los identificadores bien separados del resto del texto por espacios en blancos a derecha e izquierda, si no lo hacemos así el programa no los identificará como tales y los tomará literalmente como un texto. Si en alguna ocasión es preciso que la palabra que sustituya al identificador aparezca junto a otros caracteres que no sean blancos (signos ortográficos, paréntesis, el path de un fichero...etc.) podemos recurrir al  identificador $+, este lo único que hace es eliminar los espacios en blanco que tiene a derecha e izquierda en la presentación final de la línea. 

Por ejemplo: 
  /fichero /say La ruta de mi cliente de IRC es: C:\mirc\ $+ $1   
Si escribimos:  
  /fichero mirc32.exe    
obtendremos la línea:  
  "La ruta de mi cliente de IRC es: C:\mirc\mirc32.exe"  
Una variante interesante de los identificadores $nº, $?, $$nº, y $$? la podemos lograr anteponiendo a los mismos el símbolo #; esto nos evita el tener que escribir siempre este símbolo antes del nombre cuando queramos introducir el nombre de un canal, puesto que el programa lo insertará automáticamente. Por ejemplo: 
  /j /join #$?="En que canal quieres entrar? (sin #)"   
Otra opción muy útil de la creación de aliases es la especificación de alias dirigidos a las teclas de función, es decir el nombre o patrón se asocia con las teclas F1 a F12, o bien de combinaciones de estas con los botones Shift y Control; de este modo solo es necesario pulsar la combinación de teclas correspondiente para que el alias se ejecute. 
 
Ejemplos: 
  /F1 /say Hola $$?="escribe el nick a saludar:" $+ . Bienvenido al canal   
Con este alias no necesitamos más que pulsar F1 para que el programa nos pida un nick, y emita un mensaje de saludo a ese nick en el canal activo. 
  /sF2 /quit Adiós amigos, hasta pronto!   
Con este alias desconectaremos del server dejando un mensaje de despedida al pulsar las teclas Shift + F2 
  /cF3 /ctcp $$?="nick?" ping   
Con este alias podremos enviar un ping solo pulsando la combinación Control + F3 y escribiendo el nick que recibirá el ping. 

De lo visto hasta ahora se deduce fácilmente que la principal potencia de los alias reside en el uso de los identificadores $; hay otros muchos además de los que hemos descrito aquí, que proporcionan diferentes utilidades, una lista más detallada de estos se puede consultar en el apartado IDENTIFICADORES DEL mIRC. Otros recursos como el uso de variables, la instrucción if-else, ...etc. tienen también su capitulo aparte.

<---Atrás